### Copyright (C) 1997 John D. Hardin
### This program is free software; you can redistribute it and/or modify
### it under the terms of the GNU General Public License as published by
### the Free Software Foundation; either version 2 of the License, or
### (at your option) any later version.
###
### This program is distributed in the hope that it will be useful,
### but WITHOUT ANY WARRANTY; without even the implied warranty of
### MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
### GNU General Public License for more details.
###
### You should have received a copy of the GNU General Public License
### along with this program; if not, write to the Free Software
### Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.

### $Id: allowhost.template,v 2.21 1999-05-24 13:18:54-07 jhardin Exp $


proc allowhosts {} {
    # Allow / Services (Per-Host, Internet Hosts)

    Desc "Per-Internet-Host Services Allowed"

    ShortDesc "Per-Internet-Host Services Allowed"

    Header head1 -text "Per-Internet-Host Services Allowed"\
            -background gray\
            -help "Services are things like Telnet for logins, SMTP for email, FTP for file transfer,"\
            "HTTP for Webs, and so forth. Certain services you may want to provide even if your default"\
            "policy is \"deny\", for example, HTTP to serve web pages."\

    Label label1 -text "Firewall support"\
            -textafter "compiled into the kernel."\
            -default "is"\
            -packFrame:anchor center \
            -help "Firewall support must be compiled into the kernel. If it is not,"\
            "then you must configure and build a new kernel; see the Kernel HOWTO for"\
            "instructions."

    Entry hostIP -text "Internet Host"\
            -help "The name or unique IP address of a computer on the Internet,"\
            "or a network address (to match all hosts on a particular network).\n"\
            "WARNING: If you enter a name then that name should probably be in your /etc/hosts file."\
            "If you access the Internet via dialup there is no guarantee that the ipfwadm"\
            "command will be able to look up the name using DNS."\
            "\n\nIf you provide a file name here, the IP addresses and netmasks will be retrieved"\
            "from that file at the time the firewall script is run. This allows you to modify the"\
            "list of Internet hosts permitted to access your local network without having to"\
            "regenerate the firewall script; simply edit the IP address file and re-run the"\
            "generated firewall script."

    global MaskList
    ComboBox hostnetmask -text "Network Mask"\
            -count 8 -noedit 1\
            -entries $MaskList\
            -help "If you entered the IP address or name for a specific host, select \"32: 255.255.255.255\" -"\
            "this means that the address must match exactly for the packet to be accepted.\n"\
            "If you entered a network address, or if you entered a host IP or name and want to match all of the"\
            "hosts on the same network as that host, select the appropriate netmask for that network.\n"\
            "WARNING: If you select \"0: 0.0.0.0\" then this rule will apply to *all* hosts on the Internet."

    global ServiceList
    ComboBox allowservice -text "Service to allow"\
            -count 10\
            -help "Select a service from the list, or enter one in the form port#(:port#)/\[tcp|udp|icmp\]."\
              "For example, to allow HTTP requests, enter \"80/tcp\". See the file"\
              "/etc/services (from which this list was generated) for a list of services with some comments,"\
              "or consult your ISP."\
            -entries $ServiceList

    Radio direction -defaultIndex 0\
            -entryhelp {\
            "Inbound" "Service requests coming in from host(s) on the Internet."\
            "Outbound" "Service requests going out to host(s) on the Internet."\
            }

    Line line1

    Frame frame1 -entries {hostIP hostnetmask}
    Frame frame2 -entries {allowservice direction}
    Frame frame3 -entries {frame1 frame2 line1} -orient top

    ExtEntry allowedhosts -entries frame3 -count 5

    ShowPage {
      global FirewallInKernel
      if {$FirewallInKernel == 0} {
        set label1 "is not"
        Disable allowedhosts
      } else {
        set label1 "is"
        Enable allowedhosts
      }
    }

    Save {
      global IPFWADM
      global ISPPort
      global LocalNetIP
      global LocalNetMask
      global PERL
      global ParseIP
      global MatchService
      global MatchPort
      if {$IPFWADM == "" || $ISPPort == ""} {
        # nothing
      } else {

        forevery allowedhosts {

          # If host IP is actually a filename, then parse the IP addresses from the file
          set fromfile 0
          if {[file exists $hostIP]} {
            if {$PERL != ""} {
              set fromfile 1
              set host "\$IP_TO_ALLOW"
              print
              print "# process Internet host permissions from file $hostIP"
              print "if \[ -s $hostIP ]"
              print "then"
              print "  $PERL -n -e '$ParseIP' $hostIP | \\"
              print "  while read IP_TO_ALLOW"
              print "  do"
            } else {
              print
              print "# perl not found - cannot set Internet host rules from $hostIP."
              print "# Install perl, then regenerate the firewall file."
              # generate do-nothing rules
              set host "0.0.0.0/32"
            }
          } else {
            # get the net mask for the host
            regexp {([0-9]+): } $hostnetmask junk maskbits
            set host "$hostIP/$maskbits"
          }

          set service $allowservice
          if {[regexp "$MatchPort" $service junk port junk prot]} {
            set ACK [pick {$prot == "tcp"} " \$ConnEstablished" ""]
            # if there's a description before or after the port spec, retrieve it.
            set descr ""
            if {![regexp "^(\[ A-Za-z0-9\\-_\]+)\[ \t\]+" $service junk descr]} {
              # not before. try after.
              regexp "\[ \t(\]+(\[ A-Za-z0-9\\-_\]+)" $service junk descr
            }
            if {$descr != ""} {
              set descr " ($descr)"
            }

            if {$direction(index) == 0} {	# inbound (specified host is SOURCE)
              if {$prot == "icmp"} {
                print "# Allow ICMP message $port$descr from Internet host/network $host to anyone on the local net"
                print $IPFWADM "-I -a accept \$INET -P $prot -S $host $port -D \$INET_IP"
                if {${isp@on_internet}} {
                  if {$LocalNetIP != "" && ${masq@masquerade} == 0} {
                    print $IPFWADM "-I -a accept \$INET -P $prot -S $host $port -D \$LNET"
                    print $IPFWADM "-F -a accept \$LETH -P $prot -S $host $port -D \$LNET"
                    print $IPFWADM "-O -a accept \$LETH -P $prot -S $host $port -D \$LNET"
                  }
                }
              } else {
                # TCP or UDP
                print "# Allow Internet host/network $host to request $prot port $port$descr from anyone on the local net"
                print $IPFWADM "-I -a accept \$INET -P $prot -S $host -D \$INET_IP $port"
                print $IPFWADM "-O -a accept \$INET -P $prot$ACK -D $host -S \$INET_IP $port"
                if {${isp@on_internet}} {
                  if {$LocalNetIP != "" && ${masq@masquerade} == 0} {
                    print $IPFWADM "-I -a accept \$INET -P $prot -S $host -D \$LNET $port"
                    print $IPFWADM "-F -a accept \$LETH -P $prot -S $host -D \$LNET $port"
                    print $IPFWADM "-O -a accept \$LETH -P $prot -S $host -D \$LNET $port"
                    print $IPFWADM "-I -a accept \$LETH -P $prot$ACK -D $host -S \$LNET $port"
                    print $IPFWADM "-F -a accept \$INET -P $prot$ACK -D $host -S \$LNET $port"
                    print $IPFWADM "-O -a accept \$INET -P $prot$ACK -D $host -S \$LNET $port"
                  }
                }
              }
            } else {	# outbound (specified host is DEST)
              if {$prot == "icmp"} {
                print "# Allow anyone on the local net to send ICMP message $port$descr to Internet host/network $host"
                print $IPFWADM "-O -a accept \$INET -P $prot -S \$INET_IP $port -D $host"
                if {${isp@on_internet}} {
                  if {$LocalNetIP != "" && ${masq@masquerade} == 0} {
                    print $IPFWADM "-I -a accept \$LETH -P $prot -S \$LNET $port -D $host"
                    print $IPFWADM "-F -a accept \$INET -P $prot -S \$LNET $port -D $host"
                    print $IPFWADM "-O -a accept \$INET -P $prot -S \$LNET $port -D $host"
                  }
                }
              } else {
                # TCP or UDP
                print "# Allow anyone on the local net to request $prot port $port$descr from Internet host/network $host"
                print $IPFWADM "-O -a accept \$INET -P $prot -S \$INET_IP -D $host $port"
                print $IPFWADM "-I -a accept \$INET -P $prot$ACK -D \$INET_IP -S $host $port"
                if {${isp@on_internet}} {
                  if {$LocalNetIP != "" && ${masq@masquerade} == 0} {
                    print $IPFWADM "-I -a accept \$LETH -P $prot -S \$LNET -D $host $port"
                    print $IPFWADM "-F -a accept \$INET -P $prot -S \$LNET -D $host $port"
                    print $IPFWADM "-O -a accept \$INET -P $prot -S \$LNET -D $host $port"
                    print $IPFWADM "-I -a accept \$INET -P $prot$ACK -D \$LNET -S $host $port"
                    print $IPFWADM "-F -a accept \$LETH -P $prot$ACK -D \$LNET -S $host $port"
                    print $IPFWADM "-O -a accept \$LETH -P $prot$ACK -D \$LNET -S $host $port"
                  }
                }
              }
            }

            if {$prot == "tcp" && $port == "21"} {
              # ftp service...
              # add special handling for ftp-data "reverse connection"
              # with type-of-service adjustment for bulk data
              print "#  The previous was an FTP control channel - permit the FTP data channel,"
              print "#  with Type-of-Service set to bulk data"
              if {$direction(index) == 0} {	# inbound (specified host is SOURCE)
                print $IPFWADM "-O -a accept \$INET -P $prot -S \$INET_IP 20 -D $host 1025:65535 -t 0xE1 0x08"
                print $IPFWADM "-I -a accept \$INET -P $prot$ACK -D \$INET_IP 20 -S $host 1025:65535 -t 0xE1 0x08"
                if {${isp@on_internet}} {
                  if {$LocalNetIP != "" && ${masq@masquerade} == 0} {
                    print $IPFWADM "-I -a accept \$LETH -P $prot -S \$LNET 20 -D $host 1025:65535 -t 0xE1 0x08"
                    print $IPFWADM "-F -a accept \$INET -P $prot -S \$LNET 20 -D $host 1025:65535"
                    print $IPFWADM "-O -a accept \$INET -P $prot -S \$LNET 20 -D $host 1025:65535"
                    print $IPFWADM "-I -a accept \$INET -P $prot$ACK -D \$LNET 20 -S $host 1025:65535 -t 0xE1 0x08"
                    print $IPFWADM "-F -a accept \$LETH -P $prot$ACK -D \$LNET 20 -S $host 1025:65535"
                    print $IPFWADM "-O -a accept \$LETH -P $prot$ACK -D \$LNET 20 -S $host 1025:65535"
                  }
                }
              } else {	# outbound (specified host is DEST)
                print $IPFWADM "-I -a accept \$INET -P $prot -S $host 20 -D \$INET_IP 1025:65535 -t 0xE1 0x08"
                print $IPFWADM "-O -a accept \$INET -P $prot$ACK -D $host 20 -S \$INET_IP 1025:65535 -t 0xE1 0x08"
                if {${isp@on_internet}} {
                  if {$LocalNetIP != "" && ${masq@masquerade} == 0} {
                    print $IPFWADM "-I -a accept \$INET -P $prot -S $host 20 -D \$LNET 1025:65535 -t 0xE1 0x08"
                    print $IPFWADM "-F -a accept \$LETH -P $prot -S $host 20 -D \$LNET 1025:65535"
                    print $IPFWADM "-O -a accept \$LETH -P $prot -S $host 20 -D \$LNET 1025:65535"
                    print $IPFWADM "-I -a accept \$LETH -P $prot$ACK -D $host 20 -S \$LNET 1025:65535 -t 0xE1 0x08"
                    print $IPFWADM "-F -a accept \$INET -P $prot$ACK -D $host 20 -S \$LNET 1025:65535"
                    print $IPFWADM "-O -a accept \$INET -P $prot$ACK -D $host 20 -S \$LNET 1025:65535"
                  }
                }
              }
            }

          } else {
            print "# Syntax error on host $host: service \"$service\" unparseable."
            tk_dialog .warning "Warning" "Syntax error on host $host: service \"$service\" unparseable." info 0 OK
          }

          if {$fromfile != 0} {
            # finish up the shell script loop
            print "  done"
            print "fi"
            print
          }
        }
      }
    }
}
