/*
 *  SPL - The SPL Programming Language
 *  Copyright (C) 2004, 2005  Clifford Wolf <clifford@clifford.at>
 *
 *  This program is free software; you can redistribute it and/or modify
 *  it under the terms of the GNU General Public License as published by
 *  the Free Software Foundation; either version 2 of the License, or
 *  (at your option) any later version.
 *
 *  This program is distributed in the hope that it will be useful,
 *  but WITHOUT ANY WARRANTY; without even the implied warranty of
 *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 *  GNU General Public License for more details.
 *
 *  You should have received a copy of the GNU General Public License
 *  along with this program; if not, write to the Free Software
 *  Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
 *
 *  example40.spl: Walking thru the contexts examples
 */

var barfoo = "Barfoo from root context.";

function test1()
{
	function create_foobar(value)
	{
		var [*].foobar = value;
	}

	create_foobar(42);
	debug foobar;
}

function test2()
{
	object A {
		var foobar = "I am 'foobar' from object A.";
	}
	object B {
		method print_foobar() {
			if (declared foobar)
				debug foobar;
			else
				debug "Variable 'foobar' not found.";
		}
	}

	B.print_foobar();

	B.[*] = A;
	B.print_foobar();
}

function test3()
{
	var barfoo = "Barfoo from function test3().";

	object A {
		var foobar = "Foobar from object 'A'.";
	}

	object B {
		var foobar = "Foobar from object 'B'.";
	}

	object C A {
		method test() {
			debug foobar;
			debug barfoo;
		}
	}

	(new C()).test();

	C[+] = B;
	(new C()).test();

	C[*] = [/];
	(new C()).test();
}

test1();
test2();
test3();

