Chicken » Unit library

## Unit library

This unit contains basic Scheme definitions. This unit is used by default, unless the program is compiled with the `-explicit-use` option.

### Arithmetic

#### add1/sub1

`(add1 N)` procedure
`(sub1 N)` procedure

  Adds/subtracts 1 from `N`.

#### Binary integer operations

`(bitwise-and N1 ...)` procedure
`(bitwise-ior N1 ...)` procedure
`(bitwise-xor N1 ...)` procedure
`(bitwise-not N)` procedure
`(arithmetic-shift N1 N2)` procedure

  Binary integer operations. `arithmetic-shift` shifts the argument `N1` by `N2` bits to the left. If `N2` is negative, then `N1` is shifted to the right. These operations only accept exact integers or inexact integers in word range (32 bit signed on 32-bit platforms, or 64 bit signed on 64-bit platforms).

#### bit-set?

`(bit-set? N INDEX)` procedure

  Returns `#t` if the bit at the position `INDEX` in the integer `N` is set, or `#f` otherwise. The rightmost/least-significant bit is bit 0.

#### Arithmetic fixnum operations

`(fx+ N1 N2)` procedure
`(fx- N1 N2)` procedure
`(fx* N1 N2)` procedure
`(fx/ N1 N2)` procedure
`(fxmod N1 N2)` procedure
`(fxneg N)` procedure
`(fxmin N1 N2)` procedure
`(fxmax N1 N2)` procedure
`(fxand N1 N2)` procedure
`(fxior N1 N2)` procedure
`(fxxor N1 N2)` procedure
`(fxnot N)` procedure
`(fxshl N1 N2)` procedure
`(fxshr N1 N2)` procedure

  `fx+` and friends are arithmetic fixnum operations. These procedures do not check their arguments, so non-fixnum parameters will result in incorrect results. `fxneg` negates its argument.

  On division by zero, `fx/` and `fxmod` signal a condition of kind `(exn arithmetic)`.

  `fxshl` and `fxshr` perform arithmetic shift left and right, respectively.

#### Fixnum comparison and predicates

`(fxodd? N)` procedure
`(fxeven? N)` procedure
`(fx= N1 N2)` procedure
`(fx> N1 N2)` procedure
`(fx< N1 N2)` procedure
`(fx>= N1 N2)` procedure
`(fx<= N1 N2)` procedure

  Comparison of fixnums and predicates on them.

#### fixnum?

`(fixnum? X)` procedure

  Returns `#t` if `X` is a fixnum, or `#f` otherwise.

#### Fixnum limits

`most-positive-fixnum` constant
`most-negative-fixnum` constant
`fixnum-bits` constant
`fixnum-precision` constant

  Platform-specific fixnum limits.

#### Arithmetic floating-point operations

`(fp+ X Y)` procedure
`(fp- X Y)` procedure
`(fp* X Y)` procedure
`(fp/ X Y)` procedure
`(fpneg X)` procedure
`(fpmin X Y)` procedure
`(fpmax X Y)` procedure
`(fp= X Y)` procedure
`(fp> X Y)` procedure
`(fp< X Y)` procedure
`(fp>= X Y)` procedure
`(fp<= X Y)` procedure
`(fpfloor X)` procedure
`(fpceiling X)` procedure
`(fptruncate X)` procedure
`(fpround X)` procedure
`(fpsin X)` procedure
`(fpcos X)` procedure
`(fptan X)` procedure
`(fpasin X)` procedure
`(fpacos X)` procedure
`(fpatan X)` procedure
`(fpatan2 X Y)` procedure
`(fplog X)` procedure
`(fpexp X)` procedure
`(fpexpt X Y)` procedure
`(fpsqrt X)` procedure
`(fpabs X)` procedure
`(fpinteger? X)` procedure

  Arithmetic floating-point operations.

  In safe mode, these procedures throw a type error when given non-float arguments. In unsafe mode, these procedures do not check their arguments. A non-flonum argument in unsafe mode can crash the application.

  Note: `fpround` uses the rounding mode that your C library implements, which is usually different from R5RS.

#### flonum?

`(flonum? X)` procedure

  Returns `#t` if `X` is a flonum, or `#f` otherwise.

#### Flonum limits

`maximum-flonum` constant
`minimum-flonum` constant
`flonum-radix` constant
`flonum-epsilon` constant
`flonum-precision` constant
`flonum-decimal-precision` constant
`flonum-maximum-exponent` constant
`flonum-minimum-exponent` constant
`flonum-maximum-decimal-exponent` constant
`flonum-minimum-decimal-exponent` constant

  Platform-specific flonum limits.

#### finite?

`(finite? N)` procedure

  Returns `#f` if `N` is negative or positive infinity, and `#t` otherwise.

#### signum

`(signum N)` procedure

  Returns `1` if `N` is positive, `-1` if `N` is negative or `0` if `N` is zero. `signum` is exactness preserving.

### File Input/Output

#### current-output-port

`(current-output-port [PORT])` procedure

  Returns default output port. If `PORT` is given, then that port is selected as the new current output port.

  Note that the default output port is not buffered. Use `set-buffering-mode!` if you need a different behavior.

#### current-error-port

`(current-error-port [PORT])` procedure

  Returns default error output port. If `PORT` is given, then that port is selected as the new current error output port.

  Note that the default error output port is not buffered. Use `set-buffering-mode!` if you need a different behavior.

#### flush-output

`(flush-output [PORT])` procedure

  Write buffered output to the given output-port. `PORT` defaults to the value of `(current-output-port)`.

#### port-closed?

`(port-closed? PORT)` procedure

  Is the given `PORT` closed?

#### port-name

`(port-name [PORT])` procedure

  Fetch filename from `PORT`. This returns the filename that was used to open this file. Returns a special tag string, enclosed into parentheses for non-file ports. `PORT` defaults to the value of `(current-input-port)`.

#### port-position

`(port-position [PORT])` procedure

  Returns the current position of `PORT` as two values: row and column number. If the port does not support such an operation an error is signaled. This procedure is currently only available for input ports. `PORT` defaults to the value of `(current-input-port)`.

#### set-port-name!

`(set-port-name! PORT STRING)` procedure

  Sets the name of `PORT` to `STRING`.

### Files

#### delete-file

`(delete-file STRING)` procedure

  Deletes the file with the pathname `STRING`. If the file does not exist, an error is signaled.

#### directory-exists?

`(directory-exists? STRING)` procedure

  Returns `STRING` if a directory with the given pathname exists, or `#f` otherwise.

#### file-exists?

`(file-exists? STRING)` procedure

  Returns `STRING` if a file or directory with the given pathname exists, or `#f` otherwise.

#### rename-file

`(rename-file OLD NEW)` procedure

  Renames the file or directory with the pathname `OLD` to `NEW`. If the operation does not succeed, an error is signaled.

### String ports

#### get-output-string

`(get-output-string PORT)` procedure

  Returns accumulated output of a port created with `(open-output-string)`.

#### open-input-string

`(open-input-string STRING)` procedure

  Returns a port for reading from `STRING`.

#### open-output-string

`(open-output-string)` procedure

  Returns a port for accumulating output in a string.

### Feature identifiers

CHICKEN maintains a global list of features naming functionality available in the current system. Additionally the `cond-expand` form accesses this feature list to infer what features are provided. Predefined features are `chicken`, and the SRFIs (Scheme Request For Implementation) provided by the base system: `srfi-23, srfi-30, srfi-39`. If the `eval` unit is used (the default), the features `srfi-0, srfi-2, srfi-6, srfi-8, srfi-9` and `srfi-10` are defined. When compiling code (during compile-time) the feature `compiling` is registered. When evaluating code in the interpreter (csi), the feature `csi` is registered.

#### features

`(features)` procedure

  Returns a list of all registered features that will be accepted as valid feature-identifiers by `cond-expand`.

#### feature?

`(feature? ID ...)` procedure

  Returns `#t` if all features with the given feature-identifiers `ID ...` are registered.

#### register-feature!

`(register-feature! FEATURE ...)` procedure

  Register one or more features that will be accepted as valid feature-identifiers by `cond-expand`. `FEATURE ...` may be a keyword, string or symbol.

#### unregister-feature!

`(unregister-feature! FEATURE ...)` procedure

  Unregisters the specified feature-identifiers. `FEATURE ...` may be a keyword, string or symbol.

### Keywords

Keywords are special symbols prefixed with `#:` that evaluate to themselves. Procedures can use keywords to accept optional named parameters in addition to normal required parameters. Assignment to and bindings of keyword symbols is not allowed. The parameter `keyword-style` and the compiler/interpreter option `-keyword-style` can be used to allow an additional keyword syntax, either compatible to Common LISP, or to DSSSL. As long as this parameter is set to `#:suffix`, Chicken conforms to SRFI-88.

#### get-keyword

`(get-keyword KEYWORD ARGLIST [THUNK])` procedure

  Returns the argument from `ARGLIST` specified under the keyword `KEYWORD`. If the keyword is not found, then the zero-argument procedure `THUNK` is invoked and the result value is returned. If `THUNK` is not given, `#f` is returned.

      (define (increase x . args)
        (+ x (get-keyword #:amount args (lambda () 1))) )
      (increase 123)                                      ==> 124
      (increase 123 #:amount 10)                          ==> 133

  Note: the `KEYWORD` may actually be any kind of object.

#### keyword?

`(keyword? X)` procedure

  Returns `#t` if `X` is a keyword symbol, or `#f` otherwise.

#### keyword->string

`(keyword->string KEYWORD)` procedure

  Transforms `KEYWORD` into a string.

#### string->keyword

`(string->keyword STRING)` procedure

  Returns a keyword with the name `STRING`.

### Environment information and system interface

#### argv

`(argv)` procedure

  Return a list of all supplied command-line arguments. The first item in the list is a string containing the name of the executing program. The other items are the arguments passed to the application. This list is freshly created on every invocation of `(argv)`. It depends on the host-shell whether arguments are expanded ('globbed') or not.

#### exit

`(exit [CODE])` procedure

  Exit the running process and return exit-code, which defaults to 0 (Invokes `exit-handler`).

  Note that pending `dynamic-wind` thunks are not invoked when exiting your program in this way.

#### build-platform

`(build-platform)` procedure

  Returns a symbol specifying the toolset which has been used for building the executing system, which is one of the following:

      cygwin
      mingw32
      gnu
      intel
      unknown

#### chicken-version

`(chicken-version [FULL])` procedure

  Returns a string containing the version number of the CHICKEN runtime system. If the optional argument `FULL` is given and true, then a full version string is returned.

#### errno

`(errno)` procedure

  Returns the error code of the last system call.

#### get-environment-variable

`(get-environment-variable STRING)` procedure

  Returns the value of the environment variable `STRING` or `#f` if that variable is not defined. See also SRFI-98.

`(getenv STRING)` procedure

  `getenv` was removed in Chicken 4.6.4. Use `get-environment-variable` instead.

#### machine-byte-order

`(machine-byte-order)` procedure

  Returns the symbol `little-endian` or `big-endian`, depending on the machine's byte-order.

#### machine-type

`(machine-type)` procedure

  Returns a symbol specifying the processor on which this process is currently running, which is one of the following:

      alpha
      mips
      hppa
      ultrasparc
      sparc
      ppc
      ppc64
      ia64
      x86
      x86-64
      unknown

#### on-exit

`(on-exit THUNK)` procedure

  Schedules the zero-argument procedures `THUNK` to be executed before the process exits, either explicitly via `exit` or implicitly after execution of the last top-level form. Note that finalizers for unreferenced finalized data are run before exit procedures.

#### software-type

`(software-type)` procedure

  Returns a symbol specifying the operating system on which this process is currently running, which is one of the following:

      windows
      unix
      macos
      ecos
      unknown

#### software-version

`(software-version)` procedure

  Returns a symbol specifying the operating system version on which this process is currently running, which is one of the following:

      linux
      freebsd
      netbsd
      openbsd
      macosx
      hpux
      solaris
      sunos
      unknown

#### c-runtime

`(c-runtime)` procedure

  Returns a symbol that designates what kind of C runtime library has been linked with this version of the Chicken libraries. Possible return values are `static`, `dynamic` or `unknown`. On systems not compiled with the Microsoft C compiler, `c-runtime` always returns `unknown`.

#### system

`(system STRING)` procedure

  Execute shell command. The functionality offered by this procedure depends on the capabilities of the host shell. If the forking of a subprocess failed, an exception is raised. Otherwise the return status of the subprocess is returned unaltered.

  On a UNIX system, that value is the raw return value of waitpid(2), which contains signal, core dump and exit status. It is 0 on success. To pull out the signal number or exit status portably requires POSIX calls, but in a pinch you can use something like this:

      ;; Returns two values: #t if the process exited normally or #f otherwise;
      ;; and either the exit status, or the signal number if terminated via signal.
      (define (process-status rc)
        (define (wait-signaled? x) (not (= 0 (bitwise-and x 127))))
        (define (wait-signal x) (bitwise-and x 127))
        (define (wait-exit-status x) (arithmetic-shift x -8))
        (if (wait-signaled? rc)
            (values #f (wait-signal rc))
            (values #t (wait-exit-status rc))))

      #;> (process-status (system "exit 42"))
      #t
      42

### Execution time

#### cpu-time

`(cpu-time)` procedure

  Returns the used CPU time of the current process in milliseconds as two values: the time spent in user code, and the time spent in system code. On platforms where user and system time can not be differentiated, system time will be always be 0.

#### current-milliseconds

`(current-milliseconds)` procedure

  Returns the number of milliseconds since process- or machine startup.

#### current-seconds

`(current-seconds)` procedure

  Returns the number of seconds since midnight, Jan. 1, 1970.

#### current-gc-milliseconds

`(current-gc-milliseconds)` procedure

  Returns the number of milliseconds spent in major garbage collections since the last call of `current-gc-milliseconds` and returns an exact integer.

### Interrupts and error-handling

#### enable-warnings

`(enable-warnings [BOOL])` procedure

  Enables or disables warnings, depending on wether `BOOL` is true or false. If called with no arguments, this procedure returns `#t` if warnings are currently enabled, or `#f` otherwise. Note that this is not a parameter. The current state (whether warnings are enabled or disabled) is global and not thread-local.

#### error

`(error [LOCATION] [STRING] EXP ...)` procedure

  Prints error message, writes all extra arguments to the value of `(current-error-port)` and invokes the current exception-handler. This conforms to SRFI-23. If `LOCATION` is given and a symbol, it specifies the location (the name of the procedure) where the error occurred.

#### get-call-chain

`(get-call-chain [START [THREAD]])` procedure

  Returns a list with the call history. Backtrace information is only generated in code compiled without `-no-trace` and evaluated code. If the optional argument `START` is given, the backtrace starts at this offset, i.e. when `START` is 1, the next to last trace-entry is printed, and so on. If the optional argument `THREAD` is given, then the call-chain will only be constructed for calls performed by this thread.

#### print-call-chain

`(print-call-chain [PORT [START [THREAD [HEADER]]]])` procedure

  Prints a backtrace of the procedure call history to `PORT`, which defaults to `(current-output-port)`. The output is prefixed by the `HEADER`, which defaults to `"\n\tCall history:\n"`.

#### print-error-message

`(print-error-message EXN [PORT [HEADER]])` procedure

  Prints an appropriate error message to `PORT` (which defaults to the value of `(current-output-port)` for the object `EXN`. `EXN` may be a condition, a string or any other object. The output is prefixed by the `HEADER`, which defaults to `"Error:"`.

#### procedure-information

`(procedure-information PROC)` procedure

  Returns an s-expression with debug information for the procedure `PROC`, or `#f`, if `PROC` has no associated debug information.

#### quit

`(quit [RESULT])` procedure

  In the interpreter `quit` exits the currently active read-eval-print loop. In compiled code, it is equivalent to calling `exit`. See also: `repl`.

#### reset

`(reset)` procedure

  Reset program (Invokes `reset-handler`).

#### warning

`(warning STRING EXP ...)` procedure

  Displays a warning message (if warnings are enabled with `enable-warnings`) and continues execution.

### Garbage collection

#### gc

`(gc [FLAG])` procedure

  Invokes a garbage-collection and returns the number of free bytes in the heap. The flag specifies whether a minor (`#f`) or major (`#t`) GC is to be triggered. If no argument is given, `#t` is assumed. An explicit `#t` argument will cause all pending finalizers to be executed.

#### memory-statistics

`(memory-statistics)` procedure

  Performs a major garbage collection and returns a three element vector containing the total heap size in bytes, the number of bytes currently used and the size of the nursery (the first heap generation). Note that the actual heap is actually twice the size given in the heap size, because CHICKEN uses a copying semi-space collector.

#### set-finalizer!

`(set-finalizer! X PROC)` procedure

  Registers a procedure of one argument `PROC`, that will be called as soon as the non-immediate data object `X` is about to be garbage-collected (with that object as its argument). Note that the finalizer will not be called while interrupts are disabled. This procedure returns `X`.

  Finalizers are invoked asynchronously, in the thread that happens to be currently running. Finalizers for data that has become garbage are called on normal program exit. Finalizers are not run on abnormal program exit. A normal program exit does not run finalizers that are still reachable from global data.

  Multiple finalizers can be registered for the same object. The order in which the finalizers run is undefined. Execution of finalizers may be nested.

#### set-gc-report!

`(set-gc-report! FLAG)` procedure

  Print statistics after every GC, depending on `FLAG`. A value of `#t` shows statistics after every major GC. A true value different from `#t` shows statistics after every minor GC. `#f` switches statistics off.

### Other predicates and comparison operations

#### promise?

`(promise? X)` procedure

  Returns `#t` if `X` is a promise returned by `delay`, or `#f` otherwise.

#### equal=?

`(equal=? X y)` procedure

  Similar to the standard parocedure `equal?`, but compares numbers using the `=` operator, so `equal=?` allows structural comparison in combination with comparison of numerical data by value.

### String utilities

#### reverse-list->string

`(reverse-list->string LIST)` procedure

  Returns a string with the characters in `LIST` in reverse order. This is equivalent to `(list->string (reverse LIST))`, but much more efficient.

### Symbols

#### Symbol utilities

##### symbol-append

`(symbol-append SYMBOL1 ...)` procedure

  Creates a new symbol from the concatenated names of the argument symbols `(SYMBOL1 ...)`.

#### Uninterned symbols ("gensyms")

Symbols may be "interned" or "uninterned". Interned symbols are registered in a global table, and when read back from a port are identical to a symbol written before:

    (define sym 'foo)

    (eq? sym (with-input-from-string
                (with-output-to-string
                  (lambda () (write sym)))
    	    read))

      => #t

Uninterned symbols on the other hand are not globally registered and so multiple symbols with the same name may coexist:

    (define sym (gensym 'foo))   ; sym is a uninterned symbol like "foo42"

    (eq? sym (with-input-from-string    ; the symbol read will be an interned symbol
                (with-output-to-string
                  (lambda () (write sym)))
    	    read))

      => #f

    (eq? (string->uninterned-symbol "foo") (string->uninterned-symbol "foo"))

      => #f

Use uninterned symbols if you need to generate unique values that can be compared quickly, for example as keys into a hash-table or association list. Note that uninterned symbols lose their uniqueness property when written to a file and read back in, as in the example above.

##### gensym

`(gensym [STRING-OR-SYMBOL])` procedure

  Returns a newly created uninterned symbol. If an argument is provided, the new symbol is prefixed with that argument.

##### string->uninterned-symbol

`(string->uninterned-symbol STRING)` procedure

  Returns a newly created, unique symbol with the name `STRING`.

#### Property lists

As in other Lisp dialects, CHICKEN supports "property lists" associated with symbols. Properties are accessible via a key that can be any kind of value but which will be compared using `eq?`.

##### get

`(get SYMBOL PROPERTY [DEFAULT])` procedure

  Returns the value stored under the key `PROPERTY` in the property list of `SYMBOL`. If no such property is stored, returns `DEFAULT`. The `DEFAULT` is optional and defaults to `#f`.

##### put!

`(put! SYMBOL PROPERTY VALUE)` procedure

  setter: (set! (get SYMBOL PROPERTY) VALUE)

  Stores `VALUE` under the key `PROPERTY` in the property list of `SYMBOL` replacing any previously stored value.

##### remprop!

`(remprop! SYMBOL PROPERTY)` procedure

  Deletes the first property matching the key `PROPERTY` in the property list of `SYMBOL`. Returns `#t` when a deletion performed, and `#f` otherwise.

##### symbol-plist

`(symbol-plist SYMBOL)` procedure

  setter: (set! (symbol-plist SYMBOL) LST)

  Returns the property list of `SYMBOL` or sets it.

##### get-properties

`(get-properties SYMBOL PROPERTIES)` procedure

  Searches the property list of `SYMBOL` for the first property with a key in the list `PROPERTIES`. Returns 3 values: the matching property key, value, and the tail of property list after the matching property. When no match found all values are `#f`.

  `PROPERTIES` may also be an atom, in which case it is treated as a list of one element.

### Standard Input/Output

#### port?

`(port? X)` procedure

  Returns `#t` if `X` is a port object or `#f` otherwise.

#### print

`(print [EXP1 ...])` procedure

  Outputs the optional arguments `EXP1 ...` using `display` and writes a newline character to the port that is the value of `(current-output-port)`. Returns `(void)`.

#### print*

`(print* [EXP1 ...])` procedure

  Similar to `print`, but does not output a terminating newline character and performs a `flush-output` after writing its arguments.

### User-defined named characters

#### char-name

`(char-name SYMBOL-OR-CHAR [CHAR])` procedure

  This procedure can be used to inquire about character names or to define new ones. With a single argument the behavior is as follows: If `SYMBOL-OR-CHAR` is a symbol, then `char-name` returns the character with this name, or `#f` if no character is defined under this name. If `SYMBOL-OR-CHAR` is a character, then the name of the character is returned as a symbol, or `#f` if the character has no associated name.

  If the optional argument `CHAR` is provided, then `SYMBOL-OR-CHAR` should be a symbol that will be the new name of the given character. If multiple names designate the same character, then the `write` will use the character name that was defined last.

      (char-name 'space)                  ==> #\space
      (char-name #\space)                 ==> space
      (char-name 'bell)                   ==> #f
      (char-name (integer->char 7))       ==> #f
      (char-name 'bell (integer->char 7))
      (char-name 'bell)                   ==> #\bell
      (char->integer (char-name 'bell))   ==> 7

### Blobs

"blobs" are collections of unstructured bytes. You can't do much with them, but allow conversion to and from SRFI-4 number vectors.

#### make-blob

`(make-blob SIZE)` procedure

  Returns a blob object of `SIZE` bytes, aligned on an 8-byte boundary, uninitialized.

#### blob?

`(blob? X)` procedure

  Returns `#t` if `X` is a blob object, or `#f` otherwise.

#### blob-size

`(blob-size BLOB)` procedure

  Returns the number of bytes in `BLOB`.

#### blob->string

`(blob->string BLOB)` procedure

  Returns a string with the contents of `BLOB`.

#### string->blob

`(string->blob STRING)` procedure

  Returns a blob with the contents of `STRING`.

#### blob=?

`(blob=? BLOB1 BLOB2)` procedure

  Returns `#t` if the two argument blobs are of the same size and have the same content.

### Lists

#### foldl

`(foldl PROCEDURE INIT LIST)` procedure

  Applies `PROCEDURE` to the elements from `LIST`, beginning from the left:

      (foldl + 0 '(1 2 3))    ==>    (+ (+ (+ 0 1) 2) 3)

  Note that the order of arguments taken by `PROCEDURE` is different from the `SRFI-1` `fold` procedure, but matches the more natural order used in Haskell and Objective Caml.

#### foldr

`(foldr PROCEDURE INIT LIST)` procedure

  Applies `PROCEDURE` to the elements from `LIST`, beginning from the right:

      (foldr + 0 '(1 2 3))    ==>    (+ 1 (+ 2 (+ 3 0)))

### Vectors

#### vector-copy!

`(vector-copy! VECTOR1 VECTOR2 [COUNT])` procedure

  Copies contents of `VECTOR1` into `VECTOR2`. If the argument `COUNT` is given, it specifies the maximal number of elements to be copied. If not given, the minimum of the lengths of the argument vectors is copied.

  Exceptions: `(exn bounds)`

#### vector-resize

`(vector-resize VECTOR N [INIT])` procedure

  Creates and returns a new vector with the contents of `VECTOR` and length `N`. If `N` is greater than the original length of `VECTOR`, then all additional items are initialized to `INIT`. If `INIT` is not specified, the contents are initialized to some unspecified value.

#### subvector

`(subvector VECTOR FROM [TO])` procedure

  Returns a new vector with elements taken from `VECTOR` in the given range. `TO` defaults to `(vector-length VECTOR)`.

  `subvector` was introduced in CHICKEN 4.7.3.

### The unspecified value

#### void

`(void ARGUMENT ...)` procedure

  Ignores `ARGUMENT ...` and returns an unspecified value.

### Continuations

#### call/cc

`(call/cc PROCEDURE)` procedure

  An alias for `call-with-current-continuation`.

#### continuation-capture

`(continuation-capture PROCEDURE)` procedure

  Creates a continuation object representing the current continuation and tail-calls `PROCEDURE` with this continuation as the single argument.

  More information about this continuation API can be found in the paper http://repository.readscheme.org/ftp/papers/sw2001/feeley.pdf A Better API for first class Continuations by Marc Feeley.

#### continuation?

`(continuation? X)` procedure

  Returns `#t` if `X` is a continuation object, or `#f` otherwise. Please note that this applies only to continuations created by the Continuation API, but not by call/cc, i.e.: `(call-with-current-continuation continuation?)` returns `#f`, whereas `(continuation-capture continuation?)` returns `#t`.

#### continuation-graft

`(continuation-graft CONT THUNK)` procedure

  Calls the procedure `THUNK` with no arguments and the implicit continuation `CONT`.

#### continuation-return

`(continuation-return CONT VALUE ...)` procedure

  Returns the value(s) to the continuation `CONT`. `continuation-return` could be implemented like this:

      (define (continuation-return k . vals)
        (continuation-graft
          k
          (lambda () (apply values vals)) ) )

### Setters

SRFI-17 is fully implemented. For more information see: SRFI-17.

#### setter

`(setter PROCEDURE)` procedure

  Returns the setter-procedure of `PROCEDURE`, or signals an error if `PROCEDURE` has no associated setter-procedure.

  Note that `(set! (setter PROC) ...)` for a procedure that has no associated setter procedure yet is a very slow operation (the old procedure is replaced by a modified copy, which involves a garbage collection).

#### getter-with-setter

`(getter-with-setter GETTER SETTER)` procedure

  Returns a copy of the procedure `GETTER` with the associated setter procedure `SETTER`. Contrary to the SRFI specification, the setter of the returned procedure may be changed.

### Reader extensions

#### define-reader-ctor

`(define-reader-ctor SYMBOL PROC)` procedure

  Define new read-time constructor for `#,` read syntax. For further information, see the documentation for SRFI-10.

#### set-read-syntax!

`(set-read-syntax! CHAR-OR-SYMBOL PROC)` procedure

  When the reader encounters the non-whitespace character `CHAR` while reading an expression from a given port, then the procedure `PROC` will be called with that port as its argument. The procedure should return a value that will be returned to the reader:

       ; A simple RGB color syntax:

       (set-read-syntax! #\%
         (lambda (port)
           (apply vector
             (map (cut string->number <> 16)
      	    (string-chop (read-string 6 port) 2) ) ) ) )

       (with-input-from-string "(1 2 %f0f0f0 3)" read)
       ; ==> (1 2 #(240 240 240) 3)

  If `CHAR-OR-SYMBOL` is a symbol, then a so-called read-mark handler is defined. In that case the handler procedure will be called when a character-sequence of the form

      #!SYMBOL

  is encountered.

  You can undo special handling of read-syntax by passing `#f` as the second argument (if the syntax was previously defined via `set-read-syntax!`).

  Note that all of CHICKEN's special non-standard read-syntax is handled directly by the reader. To disable built-in read-syntax, define a handler that triggers an error (for example).

#### set-sharp-read-syntax!

`(set-sharp-read-syntax! CHAR-OR-SYMBOL PROC)` procedure

  Similar to `set-read-syntax!`, but allows defining new `#<CHAR> ...` reader syntax. If the first argument is a symbol, then this procedure is equivalent to `set-read-syntax!`.

#### set-parameterized-read-syntax!

`(set-parameterized-read-syntax! CHAR-OR-SYMBOL PROC)` procedure

  Similar to `set-sharp-read-syntax!`, but intended for defining reader syntax of the form `#<NUMBER><CHAR> ...`. The handler procedure `PROC` will be called with two arguments: the input port and the number preceding the dispatching character. If the first argument is a symbol, then this procedure is equivalent to `set-read-syntax!`.

#### copy-read-table

`(copy-read-table READ-TABLE)` procedure

  Returns a copy of the given read-table. You can access the currently active read-table with `(current-read-table)`.

Previous: Exceptions Next: Unit eval